pxSetCinematicBody(body%)

Параметры

body% - физическое тело

Описание

Создает управляемое тело которым можно воздействовать на физические тела кроме статических.

Смотрите так же

Пример

;Пример функции
;pxSetCinematicBody

Graphics3D 800, 600,32,2
SetBuffer BackBuffer()
SeedRnd MilliSecs ()
Global k=0,kil

PxCreateWorld(1)
pxSetGravity(0, -10, 0)

camera=CreateCamera()
light=CreateLight()
PositionEntity camera,20,55,-50
RotateEntity camera,30,30,0

plane=CreatePlane( )
EntityColor plane,0,100,200

Create_Px_Stack(25)

While Not KeyDown( 1 )

If KeyHit(57)
Create_Px_CinematicCube()
k =k+1
EndIf

time=MilliSecs ()
RenderPhysic(40,0)
Update_Px_Cube()
New_time=MilliSecs ()-time



UpdateWorld ()
RenderWorld
frames=frames+1
If MilliSecs()-render_time=>1000 fps1=frames : frames=0 : render_time=MilliSecs()
Text 10,10,"FPS: "+fps1+" dll time: "+New_time
Text 10,20,"space - create Cinematic Cube"+k

Flip 0
Wend

End


Type Px_Cube
    Field cube_body%
    Field cube_mesh%
End Type

Type Px_CinematicCube
    Field cube_body%
    Field cube_mesh%, speed#, Pitch#, yaw#, roll#, angle
End Type


Function Create_Px_CinematicCube()
c.Px_CinematicCube = New Px_CinematicCube
        c\cube_body=PxCreateCube(6,1,1, 50)
;---------- Применяем pxSetCinematicBody:-------------
        pxSetCinematicBody(c\cube_body)
        c\cube_mesh=CreateCube()

        ScaleEntity c\cube_mesh,6,1,1
        EntityColor c\cube_mesh,Rand(0,255),Rand(0,255),Rand(0,255)
        pxSetPosition(c\cube_body,Rand(-15,15),Rand(1,30),-30)

        c\angle = 0
        c\Pitch#=Rnd(-90,90)
        c\yaw#=Rnd(-20,20)
        c\roll#=Rnd(-90,90)
        c\speed #= Rnd(0.1,0.3)            
End Function

Function Update_Px_Cube()
    For ocu.Px_Cube = Each Px_Cube
        pxSetEntity(ocu\cube_mesh, ocu\cube_body)
    Next
    For c.Px_CinematicCube = Each Px_CinematicCube
        pxSetEntity(c\cube_mesh, c\cube_body)
        pxMoveCinematicBody(c\cube_body, 0, 0, c\speed)
        c\angle# = c\angle+c\yaw#
        pxSetRotation(c\cube_body,c\Pitch#, c\angle#,c\roll)
    Next
End Function

Function Create_Px_Stack(size%)
    CubeSize = 1.0
    Spacing = 0.01
    pos_y = CubeSize
    Offset = -size * (CubeSize * 2.0 + Spacing) * 0.5
    While size
        For i=0 To size-1
            ocu.Px_Cube = New Px_Cube
            Pos_x = Offset + i * (CubeSize * 2.0 + Spacing)
            ocu\cube_body=PxCreateCube(1,1,1, 10)
            ocu\cube_mesh=CreateCube()
            EntityColor ocu\cube_mesh,Rand(0,255),Rand(0,255),Rand(0,255)
            pxSetPosition(ocu\cube_body,pos_x,pos_y,0)
            kil=kil+1
            k=k+1
        Next
        Offset = Offset +CubeSize;
        pos_y = pos_y +(CubeSize * 2.0 + Spacing)
        size=size-1
    Wend
End Function

К содержанию

Нажмите здесь чтобы увидеть последнюю версию этой странички в режиме online.